home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Gold Medal Software 3
/
Gold Medal Software - Volume 3 (Gold Medal) (1994).iso
/
database
/
movies27.arj
/
INSTALL.FIL
< prev
next >
Wrap
Text File
|
1994-04-03
|
10KB
|
386 lines
' MOVIES TO GO! DOS / WINDOWS Installation Script
' Copyright 1993, ImagiSOFT, Inc.
' Version 2.7
' April 3, 1994
' Note: This installation script is written for THE FINISHING TOUCH, a
' professional installation program which is also an ImagiSOFT
' product. It is distributed with MOVIES TO GO! to make
' installation easier, and to reduce our support calls.
' This script unpacks 6 compressed files (*.PAK) which is a
' major feature of the program. For more information about
' THE FINISHING TOUCH, call ImagiSOFT at (505) 275-1920, or call
' our personal BBS number at (505) 275-9697.
' It will always have the latest shareware version of
' THE FINISHING TOUCH so you can "try before you buy".
BACKGROUND ~0\INSTALL.BIN ' load binary file background
TELESCOPE OFF
LANGUAGE ENGLISH ' may be changed to GERMAN, FRENCH, SPANISH, DANISH, or DUTCH
TELESCOPE ON
SHADOW OFF
SPACE 1500 ' if they don't have 1.5 meg free, forget it
PAUSE 300 ' wait 3 seconds
' display opening menu
:OPENING
WINOPEN 0 8 31
" INSTALLATION OPTIONS MENU"
""
"1. Install as Microsoft Windows 3.1 Application"
"2. Install as DOS Application"
"3. QUIT"
""
"SELECT ONE OF THE ABOVE: "
WINUPDATE +10 +1 30
"INSTALLATION OPTIONS MENU"
INPUT A 1 +28 +7 15
WINCLOSE
CALL TEMP_FILE ' create temporary file
EXIST ~3\1.TMP ' selected windows install
JUMP.YES WINDOWS_APP
EXIST ~3\2.TMP ' selected dos install
JUMP.YES DOS_APP
EXIST ~3\3.TMP ' exit
JUMP.YES EXIT
BEEP
CALL TMP_DEL ' delete temporary file
JUMP OPENING
' ------------------------
' install as a dos app
' ------------------------
:DOS_APP
CALL TMP_DEL ' delete temporary file
' have user set the drive
CALL ESC
DRIVE C 0 12 31 15 32 14 79
WINCLOSE
' have user set the path
CALL ESC
PATH \MOVIES 0 12 31 15 32 14 79
WINCLOSE
CALL EMPTY_DIR ' make sure directory is empty
CALL UNPACK ' unpack data files
' create movies batch file
PROMPT OFF
DELETE ~1\MOVIES.BAT 1 24 51
PROMPT ON
FILE ~1\MOVIES.BAT
"~1"
"cd ~2"
"MOVIES"
"cd \"
CALL PRINT ' print the documentation y/n?
WINOPEN 0 8 31
"MOVIES TO GO! has been successfully installed."
""
" To run it, enter the command"
" from the root directory of drive ~1."
""
""
""
""
"Press the [Enter] key to continue."
WINUPDATE +36 +3 30
"MOVIES"
WINUPDATE +7 +6 27
"THANK YOU FOR CHOOSING OUR SOFTWARE!"
WAIT +36 +9
WINCLOSE
:RUN
WINOPEN 0 11 31
"Would you like to run MOVIES TO GO! right now Y or N?"
ASK +57 +1
JUMP.NO EXIT
RUN ~1\MOVIES.BAT
' --------------------------
' install as windows app
' --------------------------
:WINDOWS_APP
' these commands set drive and path variables
DRIVE C ' set ~1 to drive c
PATH \WINDOWS ' set ~2 path
:TEST_WIN
EXIST ~1~2\WIN.COM ' check for windows
JUMP.YES WIN_INSTALL
PROMPT OFF
RD C:\WINDOWS ' the above exist command created this empty directory. if it is legitimate, this command will fail, causing no harm
PROMPT ON
EXIST ~3\1.TMP ' 1st time through, ignore beep
JUMP.YES SKIP_BEEP
BEEP
RD ~1~2 ' remove newly created, empty directory
WINOPEN 0 8 79
"Microsoft Windows is NOT found in the"
"~1~2 directory. Please try again."
""
"Press ENTER to continue."
WAIT +26 +4
WINCLOSE
' windows is in a directory other than C:\WINDOWS
:SKIP_BEEP
CALL TMP_DEL ' delete temporary file
WINOPEN 0 8 31
"To install MOVIES TO GO! to Microsoft Windows,"
"we need to know which hard drive Windows is installed on."
""
" Most people have Windows on this hard drive."
" Press ENTER if this is correct, or change to"
" the correct drive letter."
" (Press ESC to quit.)"
PROMPT OFF
DRIVE C +2 +3 17 14 32 14 79
WINCLOSE
PROMPT ON
WINOPEN 0 8 31
"We also need to know the name of the directory where Microsoft"
"Windows is installed. Most people have Windows installed in"
" this directory. Press ENTER"
" if this is OK, or input the name"
" of the directory where Windows"
" is installed."
" (Press ESC to quit.)"
PROMPT OFF
PATH \WINDOWS +1 +3 17 14 32 14 79
WINCLOSE
PROMPT ON
PROMPT OFF
JUMP TEST_WIN ' loop until valid input or quit
' you know the windows directory, now install it
:WIN_INSTALL
CALL TMP_DEL ' delete temporary file
FILE ~1~2\PROGMAN.INI ' edit program manager file - add group #504 (arbritary high number)
"Group504=~1\MOVIES\MOVIES.GRP"
PATH \MOVIES ' set ~2 path (windows group / pif file forces the directory name)
MD ~1~2 ' make the directory
CALL EMPTY_DIR ' make sure directory is empty
WINOPEN 0 20 79
"MOVIES TO GO! is being installed to the ~1~2 directory . . ."
CALL UNPACK ' unpack data files
UNPACK WINDOWS.PAK 0 10 31 32 15 79 ' windows pif, ico, and grp files
JUMP.FAIL INSTALL_FAILURE
COPY ~0~\VIEW.COM ~1~2\ 0 0 0 ' copy file viewer
WINCLOSE ' closes winopen above
CALL PRINT ' print docs y/n?
' --------------------------------
' successful install to windows
' --------------------------------
WINOPEN 0 8 31
"MOVIES TO GO! has been successfully installed in your"
"Windows environment. However, the changes won't take"
"effect until you exit Windows, then run Windows again."
""
""
""
"Press ENTER to return to Windows."
WINUPDATE +5 +5 27
"THANK YOU FOR CHOOSING OUR SOFTWARE!"
WAIT +35 +7
WINCLOSE
END
' ------------------
' error messages
' ------------------
:INSTALL_FAILURE
WINOPEN 0 8 79
"MOVIES TO GO! INSTALLATION FAILED BEFORE IT FINISHED!!"
""
"Possible reasons:"
" -- The floppy disk was damaged during shipping."
" -- Your disk drive is out of alignment."
" -- The floppy disk was removed prior to completion."
""
"Press [Enter] to Continue."
WAIT +28 +8
WINCLOSE
JUMP EXIT
' -----------
' subroutines
' -----------
:EMPTY_DIR
EXIST ~1~2\*.* ' check to see if directory is empty
JUMP.NO SKIP_SURE
EXIST ~1~2\1*.FIL ' if it is previous MOVIES TO GO! OK
JUMP.YES SKIP_SURE
WINOPEN 0 8 79
"The directory ~1~2 already exists and contains files!"
""
" Installing MOVIES TO GO! in this directory will"
" DELETE ALL THE FILES"
" in this directory prior to installing."
""
""
WINUPDATE +2 +7 78
"Are you SURE you want to install it here Y or N?"
ASK +52 +7
WINCLOSE
JUMP.YES SKIP_SURE
JUMP DOS_APP
:SKIP_SURE
PROMPT OFF ' don't show files being deleted
COPY ~1~2\NOTE.FIL ~1\NOTE.FIL 0 0 0 ' preserve users personal notes
DELETE ~1~2\*.* 1 24 51 ' delete all files in case they are
PROMPT ON ' installing a 2nd time
CALL TMP_DEL ' delete temporary file
RETURN
' delete temporary file (don't inform user)
:TMP_DEL
PROMPT OFF
DELETE ~3\~A.TMP 0 0 0
PROMPT ON
RETURN
' unpack data files
:UNPACK
SET.FILES 16 ' make sure files >=16 in autoexec.bat
UNPACK DATA.PAK 0 10 31 32 15 79 ' data files
JUMP.FAIL INSTALL_FAILURE
UNPACK TEXT.PAK 0 10 31 32 15 79 ' text version, other necessary files
JUMP.FAIL INSTALL_FAILURE
VIDEO VGA ' test for VGA or better
JUMP.NO NO_VGA ' to see whether to install graphics
:GRAPHICS_INSTALL
EXIST ~0\GRAPHICS.PAK ' prompt for 2nd disk on 720 k setup
JUMP.YES HD_DISK
WINOPEN 0 10 31
BEEP
"Please Insert Disk Number 2 in Drive ~0."
""
"Press the [Enter] key to continue."
WAIT +36 +3
WINCLOSE
JUMP GRAPHICS_INSTALL ' loop until correct disk inserted
:HD_DISK
CPU 386 ' look for 386+
JUMP.YES 386
WINOPEN 0 10 31
"The GRAPHICS VERSION May Be Slow on Your Computer."
""
""
""
"(If you decide that the graphics version is too slow, simply"
" install the software again, and answer N to this question.)"
WINUPDATE +2 +3 30
"Do You Want To Install it Anyway Y or N?"
ASK +44 +3
WINCLOSE
JUMP.NO NO_VGA
:386
FREE 1200 ' disk space for graphics version
JUMP.NO NO_VGA
UNPACK GRAPHICS.PAK 0 10 31 32 15 79 ' graphics version
JUMP.FAIL INSTALL_FAILURE
COPY ~1\NOTE.FIL ~1~2\NOTE.FIL 0 0 0 ' copy client's personal notes file back
FREE 1000 ' disk space for animated icons
JUMP.NO DONE_PACK
UNPACK ICON.PAK 0 10 31 32 15 79 ' fun stuff
JUMP.FAIL INSTALL_FAILURE
JUMP DONE_PACK
:NO_VGA ' only text version
PROMPT OFF
COPY ~1~2\TEXT.EXE ~1~2\MOVIES.EXE 1 24 51 ' rename text program
DELETE ~1~2\TEXT.EXE 1 24 51
DELETE ~1~2\ICON.ML 1 24 51
PROMPT ON
:DONE_PACK
RETURN
' print the documentation y/n?
:PRINT
WINOPEN 0 10 30
"Would you like to PRINT the 36 Page Manual Y or N?"
ASK +54 +1
WINCLOSE
JUMP.NO BYE_PRINT
WINOPEN 0 10 79
""
" Printing 36 Pages . . . "
""
PRINT ~1~2\MOVIES.TXT
WINCLOSE
JUMP.FAIL PRINTER_ERROR
JUMP BYE_PRINT
:PRINTER_ERROR
WINOPEN 0 10 79
"Your Printer is not responding. Possible problems:"
""
" -- Printer is not turned on"
" -- Printer is out of paper"
" -- Printer is not attached to LPT1 (parallel port 1)"
""
""
WINUPDATE +2 +7 78
"Do you want to try to print again Y or N?"
ASK +44 +7
WINCLOSE
JUMP.YES PRINT
:BYE_PRINT
RETURN
' create a temporary file in the default directory with a unique name based on the number input by the user
:TEMP_FILE
FILE ~3\~A.TMP
"Delete this temporary file."
RETURN
:ESC
WINOPEN 0 20 31
"(Press ESC to Quit) "
RETURN
:EXIT
CALL TMP_DEL ' delete temporary file
END